SykOz Codes

Ver el tema anterior Ver el tema siguiente Ir abajo

SykOz Codes

Mensaje  SykO el Jue Ene 06, 2011 4:41 am

SykOz Codes


1. Remplasador de texto

Código:
;Uso: $sRText(texto)
;Info: Regresa Palabras Ya Remplasadas
alias sRText {
    var %T = 1,%M = sRText.txt,%F = $lines(%M),%S = $1-,%h , %A
    while (%T <= %F) {
      %h = $gettok($read(%M,%T),1,9) | %A = $gettok($read(%M,%T),2,9)
      if (%h isin %S) { %S = $replace(%S,%h,%A) }
      inc %T
    }
    return %S
}
;Para Añadir Nuevas Palabras Para Remplasar
;Escribe:
; .sRT Palabra [Palabra Para Remplasar]
On *:Input:#: {
    if ($1 == .sRT) {
      if (!$3) { echo -a Utiliza: .sRT Palabra Palabra Para Remplaza }
      else { write sRText.txt $+($2,$chr(9),$3) | echo -a Palabra Añadida }
    }
    say $sRText($1-)
    halt
}

2. mp3 en input

Código:
;Uso: mdir
;Descripcion: setea la siguiente cancion
alias mdir {
  set %mp3dir $$sdir="Donde Estan Tus mp3"
  echo -ea [La direccion de tus mp3s es: %mp3dir $+ ]
}

;Uso: nextsong
;Descripcion: setea la siguiente cancion
alias nextsong {
  if (%mp3dir == $null) mdir
  if (%song == $null) set %song $findfile(%mp3dir,*.mp3,0)
  $iif(%song == $findfile(%mp3dir,*.mp3,0),set %song 1,inc %song)
  mplay $findfile(%mp3dir,*.mp3,%song)
}

;Uso: prevsong
;Descripcion: settea la cancion anterior
alias prevsong {
  if (%mp3dir == $null) mdir
  if (%song == $null) set %song 1
  $iif(%song == 1,set %song $findfile(%mp3dir,*.mp3,0),dec %song)
  mplay $findfile(%mp3dir,*.mp3,%song)
}

;Uso: mplay [Cancion]
;Descripcion: pone la cancion y lo anuncia
alias mplay {
  if (%mp3dir == $null) mdir
  var %song = $$1- | splay %song
  var %a = $mp3(%song).artist,%t = $mp3(%song).title,%d = $duration($calc($mp3(%song).length / 1000))
  amsg [mþ³]-[Autor: %a $+ ]-[Titulo: %t $+ ]-[Duracion: %d $+ ]-[by]-[§hÂdØw]
}

;Escribe:
;.dir = Settea la direccion en donde estan tus mp3 favoritos
;.next = Toca la siguiente cancion
;.prev = Toca la cancion anterior
;.play [N (opcional) ] = Quita el pause de la cancion | Toca la [N] cancion
;.pause = Pone pause a la cancion
;.stop = Para la cancion
;.rep = Settea modo de repeticion [Si esta On setea Off, de lo contrario setea On]
;.cont = Settea modo continuo [Si esta On setea Off, de lo contrario setea On]
on *:input:#: {
  if ($1 == .dir) mdir
  if ($1 == .next) nextsong
  if ($1 == .prev) prevsong
  if ($1 == .play) {
    if ($2) && ($2 isnum) { mplay $findfile(%mp3dir,*.mp3,$2) | set %song $2 }
    elseif ($insong.pause) { splay resume | echo -ea [Resumiendo la Cancion] }
    else { echo -ea [Especifica el [Numero] de la cancion] }
  }
  if ($1 == .pause) { splay pause | echo -ea [Cancion en Pause] }
  if ($1 == .stop) { splay stop | echo -ea [Tedeniendo La Cancion] }
  if ($1 == .rep) { set %repeat $iif(%repeat == On,Off,On) | echo -ea [Repetir: %repeat $+ ] }
  if ($1 == .cont) { set %continous $iif(%continous == On,Off,On) | echo -ea [Continuar: %continous $+ ] }
}

;Al finalisar una cancion
on *:mp3end: {
  if (%repeat == On) { mplay $filename | return }
  if (%continous == On) { nexts | return }
}

3. PicWin (Scroller de textos)



Código:
;Uso: PWs [Largo de ventana (opcional)] [Ancho de ventana(opcional)]
alias PWs {
  var %w = $iif($1,$1,300),%h = $iif($2,$2,200)
  if ($window(@Scroller)) window -c @Scroller
  window -pBkw0h +dL @Scroller2 0 0 $calc(%w -10) $calc(%h -10)
  window -pBkw0 +dL @Scroller $window(-3).w $window(-3).h $calc(%w +10) $calc(%h +10)
  drawrect -r @Scroller $rgb(0,0,0) 10 0 0 $calc(%w +10) $calc(%h +10) | drawrect -r @Scroller $rgb(155,155,155) 1 2 2 $calc(%w +6) $calc(%h +6)
  drawrect -r @Scroller $rgb(155,155,155) 1 6 6 $calc(%w -2) $calc(%h -2) | drawrect -r @Scroller $rgb(155,155,155) 1 19 0 $calc(%w - 28) 10
  drawrect -rf @Scroller $rgb(0,0,0) 1 20 1 $calc(%w - 30) 8 | var %t = °°° Picture Window Text Scroller °°°
  drawtext -r @Scroller $rgb(255,255,255) terminal 8 $calc(($calc(%w +10) - $width(%t,termina,8,1,0)) / 2 - 41) 1 %t
  drawrect -r @Scroller $rgb(155,155,155) 1 19 %h $calc(%w - 28) 10 | drawrect -rf @Scroller $rgb(0,0,0) 1 20 $calc(%h + 1) $calc(%w - 30) 8
  var %t = °°° Created by ShAdOw °°°
  drawtext -r @Scroller $rgb(255,255,255) terminal 8 $calc(($calc(%w +10) - $width(%t,termina,8,1,0)) / 2 - 25) $calc(%h + 1) %t
  set %SsT $calc(%w - (%w / 2 + 10)) | SsT @scroller2 %d
}
alias StMid return $calc(($window(@Scroller2).w - $width($1,$2,$3,1,0)) / 2 + 10)
alias SsT {
  if (!$window($1)) return
  var %i = 1,%w = $window($1).w,%h = $window($1).h | drawrect -rf $1 $rgb(40,40,40) 1 0 0 %w %h
  while (%i <= $ini($script,Texto,0)) { var %r = $readini($script,Texto,%i),%t = $gettok(%r,4-,58),%f = $gettok(%r,1,58),%s = $gettok(%r,2,58)
    if (%i != 1) { var %r2 = $readini($script,Texto,$calc(%i - 1)),%t2 = $gettok(%r2,4-,58),%f = $gettok(%r2,1,58),%s2 = $gettok(%r2,2,58) }
    var %y = $calc((%SsT + (%i * 25) + $iif(%i != 1,$height(%t2,%f2,%s2))) + $gettok(%r,3,58))
  drawtext -rp $1 $rgb(255,255,255) %f %s $StMid(%t,%f,%s) %y %t | if (%i == $ini($script,Texto,0)) var %ll = %y | inc %i }
  drawcopy -h $1 0 0 %w %h @Scroller 10 10 %w %h | $iif(%ll == -50,set %SsT $calc(%w + 25),dec %SsT)
  .timerSsT -m 1 100 SsT $1-
}

;Edita Esto
;Para Añadir Mas Lineas Solo Ve Sumando El Numero
;Ejemplo La Siguiente Linea Seria La 8, Y La Que Sigue 9
[Texto]
1=tahoma:18:20:Picture Window Text Scroller
2=tahoma:16:20:Created by
3=tahoma:12:20:ShAdOw
4=tahoma:8:20:© TheMexicanForce ®
5=tahoma:12:50:Fecha: $date
6=tahoma:12:50:Hora: $time(hh:nn:ssTT)
7=tahoma:12:50: $+ $iif($insong,Escuchas: $remove($nopath($insong.fname),.mp3),No Estas Escuchando Una Cancion)

4. Lista de ascii

Código:
;Aqui esta la lista de ascii
;Uso: /alist
alias alist {
  var %a = 1
  while (%a <= 255) {
    echo -s %a = $chr(%a)
    inc %a
  }
}

5 & 6. 2 estilos de flood

Código:
;Aqui esta el flood
;Uso: /TMFF1 Texto
;Descripcion: Manda El Texto Letra Por Letra.
;Ej.: /TMFF1 TMF
;      T
;      M
;      F
;Uso: /TMFF2 Texto
;Descripcion: Manda El Texto Letra Por Letra.
;Ej.: /TMFF2 TMF
;      F
;      M
;      T
alias TMFF1 {
  var %TMF = 1
  while (%TMF <= $len($1-)) {
    if ($mid($1-,%TMF,1)) say $v1
    inc %TMF
  }
}
alias TMFF2 {
  var %TMF = $len($1-)
  while (%TMF >= 1) {
    if ($mid($1-,%TMF,1)) say $v1
    dec %TMF
  }
}

7. Whois a todo el canal

Código:
;Aqui esta el whois a todo un canal
;Uso: /wChan
alias wChan {
  var %w 1
  while ($nick(#,%w)) {
    whois $v1
    inc %w
  }
}

8. Identificador para modificar tus textos

Código:
;Uso: $sStyle(C1,C2,Texto)
;Ejemplo: $sStyle(clrt+k12clrt+b^,clrt+bcrlt+k0,Texto Con Color Y Negrita!!!)
alias sstyle {
  var %s = 1,%l ,%r ,%t
  while ($gettok($3-,%s,32)) {
    %l = $1 $+ $left($v1,1)
    %r = $2 $+ $right($v1,-1)
    %t = %t $+(%l,%r)
    inc %s
  }
  return %t
}

9. Manejador de privados (queries)

Código:
alias pvsayuda {
echo -s Los Siguientes Comandos Solo Funcionan En Los Canales
echo -s  !pva nick  Para Aceptar Que Nick Pueda Mandarte Un Privado
echo -s  !pvda nick  Para No Aceptar Que Nick Pueda Mandarte Un Privado
}
on *:input:#: {
  if (!pva == $strip($1)) && ($2) { writeini $scriptdirpvs.ini allowed $2 Si | msg $active Status de $2 : $readini($scriptdirpvs.ini,allowed,$2) acepto pv }
  if (!pvda == $strip($1)) && ($2) { writeini $scriptdirpvs.ini allowed $2 No | msg $active Status de $2 : $readini($scriptdirpvs.ini,allowed,$2) acepto pv  }
}
on *:open:?: {
  if (!$ispvallowed($nick)) {
    msg $nick 14,1¤0,1¤14,1¤1,1–0,1No Acepto Privados Por El Momento1,1–14,1¤0,1¤14,1¤ 14,1AntiPrivado By 5,1–4,1»14,1§15,1h0,1Âd15,1Ø14,1w4,1«5,1–
    close -m $nick | echo -s  $nick  Kiso Mandarte un PV | halt
  }
}
alias ispvallowed return $iif($readini($scriptdirpvs.ini,allowed,$1) == Si,$true,$false)

10. Creador de inputs (/pIAyuda)

Código:
;Info: Ayuda de Comandos
alias pIAyuda { var %e = echo $color(info2) -a »
    %e $+(,$str(–,55),)
    %e  Ayuda Sobre Creador de Inputs 
    %e  Nota: Todos Los Comandos Solo Pueden Ser Utilisados en los Canales
    %e
    %e Para Añadir Un Comando Escribe:
    %e .+Com [Input] [Comando]
    %e
    %e Ejemplo: .+com !msn say Mi msn es: syko-c5@live.com
    %e !msn es el [Input] y say Mi msn es: syco-c5@live.com  es el [comando]
    %e
    %e Cuando Escribas el [Input] en un canal, se activara el [Comando]
    %e
    %e Para Borrar Un Comando Escribe:
    %e .-com [Input]
    %e
    %e Para Ver La Lista De Comandos Escribe:
    %e .clist
    %e $+(,$str(–,55),)
}

;Info: Inputs (comandos)
On *:Input:#: { var %dir Comandos.ini
    if ($1 == .+com) {
      if (!$2) || (!$3) { echo -a Sintasis Incorrecto Intenta: .+com [Input] [Comando] }
      else {
        writeini %dir Com $2 $tmfck($3-)
        echo -a Comando Añadido Input: $2 Comando: $3-
      }
    }
    if ($1 == .-com) {
      if (!$2) { echo -a Sintasis Incorrecto Intenta: .-com [Input] }
      else {
        if (!$readini(%dir,Com,$2)) { echo -a El Comando No Existe. }
        else {
          remini %dir Com $2
          echo -a Comando Borrado Input: $2
        }
      }
    }
    if ($1 == .clist) {
      if (!$ini(%dir,Com,0)) { echo -a No Tienes Comandos... }
      else {
        echo -a Lista de Comandos:
        var %i 1
        while (%i <= $ini(%dir,Com,0)) {
          var %inp = $ini(%dir,Com,%i),%com = $readini(%dir,Com,%inp))
          echo -a Input: %inp Comando: $tmfdk(%com)
          inc %i
        }
        echo -a Fin de Comandos.
      } 
    }
    if ($readini(%dir,Com,$1)) { $tmfdk($v1) }
}

;Info: Alias
alias tmfck return $replace($1-,$chr(3),<k>,$chr(2),<b>,$chr(31),<u>,$chr(22),<r>,$chr(15),<o>)
alias tmfdk return $replace($1-,<k>,$chr(3),<b>,$chr(2),<u>,$chr(31),<r>,$chr(22),<o>,$chr(15))

Animaciones en PicWin


1. Canal #eScripting - Intro 1

Código:
;Codigo: simple intro del canal #eScripting Intro by SykO - TheMexicanForce
;uso: /intro
;+info: da click y manten precionado tu mouse para poder mover la ventana.
;      da doble click y la ventana se cierra.
alias intro { var %w @eScripting | if ($window(%w)) window -c %w | window -kBpCd +d %w 0 0 300 150 | drawrect -r %w $rgb(0,0,90) 1 0 0 300 150
  set %eSi.Tx $replace(- Bienvenidos A La Introduccion Del Canal #eScripting - ­­­TheMexicanForce & eScripting Haciendo Crecer La Comunidad De $&
    mIRC Scripting!!! $chr(255) ¯-¯ Una Produccion De SykO ®-® $chr(255) *Inspirado Por El Codigo: "Star Wars Scroll" De StanZ* $&
    $str($chr(255),5),$chr(32),$chr(255)) | set %eSi.F 1 | set %eSi.C 1 | titlebar %w Intro by SykO | intro1 %w
}
alias -l intro1 { if (!$window($1)) { window -c $+($1,1) | halt } | if (!$window($+($1,1))) window -kBph +d $+($1,1) 0 0 300 150
  drawrect -rf $+($1,1) $rgb(0,0,10) 1 1 1 298 148 | set %eSi.Tx $+($right(%eSi.Tx,-1),$left(%eSi.Tx,1))
  var %s 1 | while (%s <= 298) { var %c = $r(90,150) | drawrect -rf $+($1,1) $rgb(0,$calc(%c - 90),%c) 1 %s 1 6 10 | inc %s 6 }

  ;Si Quitas los ";" de estas cuatro lineas de abajo le da un efecto de luzes rojas debajo de laz nuves.
  ; var %s 1 | while (%s <= 10) { drawdot -rf $+($1,1) $rgb(255,0,0) 1 $r(2,296) 85 | drawdot -rf $+($1,1) $rgb(255,0,0) 1 $r(2,296) 90
  ;  drawdot -rf $+($1,1) $rgb(255,0,0) 1 $r(2,296) 100 | drawdot -rf $+($1,1) $rgb(255,0,0) 1 $r(2,296) 110
  ;  drawdot -rf $+($1,1) $rgb(255,0,0) 1 $r(2,296) 120 | drawdot -rf $+($1,1) $rgb(255,0,0) 1 $r(2,296) 130
  ; drawdot -rf $+($1,1) $rgb(255,0,0) 1 $r(2,296) 140 | inc %s }

  $iif(%eSi.Cl >= 400,set %eSi.Cl -10,inc %eSi.Cl $r(3,8)) | var %t = Ù Ù Ù Ù Ù Ù
  drawtext -r $+($1,1) $rgb(255,255,255) webdings 90 $calc(%eSi.Cl - 20) -2 %t
  drawtext -r $+($1,1) $rgb(255,255,255) webdings 90 $calc(%eSi.Cl - 440) -2 %t
  drawtext -r $+($1,1) $rgb(255,255,255) webdings 90 %eSi.Cl 15 %t
  drawtext -r $+($1,1) $rgb(255,255,255) webdings 90 $calc(%eSi.Cl - 420) 15 %t
  drawtext -r $+($1,1) $rgb(255,255,255) webdings 90 $calc(%eSi.Cl - 20) 30 %t
  drawtext -r $+($1,1) $rgb(255,255,255) webdings 90 $calc(%eSi.Cl - 440) 30 %t
  drawline -r $+($1,1) $rgb(0,0,90) 1 1 11 300 11 | drawtext -rc $+($1,1) $rgb(50,110,250) terminal 9 1 2 298 8 %eSi.Tx
  $iif(%eSi.F == 55,goto new,inc %eSi.F)
  if (%eSi.C == 1) %t = #eScripting
  if (%eSi.C == 2) %t = Un Canal Para mIRC Scripters
  if (%eSi.C == 3) %t = Un Canal Para Aprender y Ayudar
  if (%eSi.C == 4) %t = Un Canal Para Compartir
  if (%eSi.C == 5) %t = ¡Un Canal Para Ti!
  if (%eSi.C == 6) %t = *** $me ***
  if (%eSi.C == 7) %t = ¡¡¡Te Esperamos!!!
  if (%eSi.C >= 8) %t = $chr(160)
  if (%eSi.C == 9) %t = TheMexicanForce™ - SykO
  var %m = $calc((298 - $width(%t,tahoma,%eSi.F)) / 2) | drawtext -r $+($1,1) $rgb(50,110,255) tahoma %eSi.F %m 90 %t
  goto copy | :new | set %eSi.F 1 | $iif(%eSi.C == 10,set %eSi.C 1,inc %eSi.C)
  :copy | drawcopy $+($1,1) 1 1 298 148 $1 1 1 | .timereSi -m 1 150 intro1 $1
}
menu @eScripting {
  sclick { eScmOve $mouse.x $mouse.y }
  dclick { window -c @eScripting }
}
alias -l eScmOve { window @eScripting $calc($mouse.dx - $1) $calc($mouse.dy - $2) | if ($mouse.key & 1) .timereScmOve -m 1 0 eScmOve $1- }

2. Canal #eScripting - Intro 2

Código:
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
; eScripting IntrO #2 - nO OficiaL
; CreAdO pOr •[ShOwInG]×[CrEaTiViTy]•™ •[SykO]•
; CopyWrong © A La ChiNgAdA CoN El CreditO ®
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
; PaRa AbRiR UtilizA  : /s-eIntrO
; PaRa CeRrAr UtilizA : dObLe-CliCk eN La VeNtAnA
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
alias s-eIntrO { window -BCdfkopz +dl @s-eIntrO -1 -1 $window(-1).w $window(-1).h | s-eDrAw }
alias -l s-eDrAw { var %w = @s-eIntrO,%l = $iif($1 isnum,$1,1),%tx = $iif($2 isnum,$2,$calc($window(%w).w + 50)),%s = $iif($3 isnum,$3,1),%t = SykO
  if (!$window(%w)) return | if (%s == 1) drawrect -rfn %w $rgb(0,0,0) 1 0 0 $window(%w).w $window(%w).h | if (%l == 1) %t = #eScripting
  if (%l == 2) %t = Canal de mSL | if (%l == 3) %t = AyudA PaRa: | if (%l == 4) %t = AddOnS | if (%l == 5) %t = DLLs | if (%l == 6) %t = ScRiPtS
  if (%l == 7) %t = RemOteS | if (%l == 8) %t = ¡EntRa! | if (%l == 9) %t = ¿DiablitoX nO AyudA? | if (%l == 10) %t = ¡Le dAmOs KiCk!
  if (%l == 11) %t = ¿[R]a[M]i[R]o nO AyudA? | if (%l == 12) %t = ¡Le dAmOs KiCk! | if (%l == 13) %t = CrEadO PoR: | if (%l == 14) %t = SykO
  if (%l == 15) %t = Visita: | if (%l == 16) %t = Www.eScripting.Net | if (%l == 17) %t = Y | if (%l == 18) %t = Www.SykO.At.Ua | if (%l == 19) %t = $chr(160)
  var %x = $calc(($window(%w).w - $width(%t,tahoma,%s,1,0)) / 2),%y = $calc($window(%w).h / 2) | drawtext -ron %w $rgb(0,0,0) tahoma %s %x %y %t
  drawtext -ron %w $rgb(0,40,$calc(5 + %s)) tahoma %s %x %y %t | %t = •[#eScripting]×[IntrO]• •[CreAdO]×[pOr]• •[ShOwInG]×[CrEaTiViTy]•™ •[SykO]•
  drawrect -rfn %w $rgb(0,0,0) 1 0 $calc($window(%w).h - 25) $window(%w).w 25 | drawtext -rn %w $rgb(200,200,200) tahoma 12 %tx $calc($window(%w).h - 19) %t
  drawtext -rn %w $rgb(200,200,200) tahoma 12 %tx $calc($window(%w).h - 17) %t | drawtext -rn %w $rgb(200,200,200) tahoma 12 %tx $calc($window(%w).h - 19) %t
  drawtext -rn %w $rgb(200,200,200) tahoma 12 %tx $calc($window(%w).h - 17) %t | drawtext -rn %w $rgb(0,0,0) tahoma 12 %tx $calc($window(%w).h - 18) %t
  drawcopy -n %w 0 $calc($window(%w).h - 25) $window(%w).w 25 %w 0 0 | drawrect -rcn %w $rgb(50,100,200) 2 0 0 $window(%w).w $window(%w).h

  ; WaTchA lO SiGuieNte - EffeCtO ChidO PerO nO RecOmeNdAdO
  ;drawrot -cfn %w %s 0 0 $window(%w).w $window(%w).h

  var %1 = $iif(%s == 200,$iif(%l != 19,$calc(%l + 1),1),%l),%2 = $iif(%tx <= $calc(($width(%t,tahoma,9,0,0) + 50) * -1),$calc($window(%w).w + 50),$calc(%tx - 2))
  var %3 = $iif(%s != 200,$calc(%s + 1),1) | drawdot %w | .timers-eIntrO -m 1 25 s-eDrAw %1 %2 %3
}
menu @s-eIntrO {
  dclick: window -c @s-eIntrO
}

3. ShOwInG CrEaTiViTy™ - (/sc)

Código:
alias sc { window -BCdkhopw0z +d $swin -1 -1 305 200 | scani | window -a $swin | window $swin $+(",$mircexe,") 15 }
alias -l swin return @ShOwInG-CrEaTiViTy
alias -l scani { var %S = $iif($1 == $null,16749378,$1),%y = $iif(!$2,252,$2),%k = $iif($3,$3,1),%O = $iif($4,$4,1),%z ,%C ,%r = 1 | if (!$window($swin)) return | drawrect -rfn $swin 0 1 0 0 305 200 | drawtext -ron $swin %S tahoma 62 3 4 ShOwInG | drawtext -ron $swin %S tahoma 62 3 6 ShOwInG
  drawtext -ron $swin %S tahoma 62 5 4 ShOwInG | drawtext -ron $swin %S tahoma 62 5 6 ShOwInG | drawtext -ron $swin 0 tahoma 62 4 5 ShOwInG | drawtext -ron $swin %S tahoma 55 0 122 CrEaTiViTy | drawtext -ron $swin %S tahoma 55 0 124 CrEaTiViTy
  drawtext -ron $swin %S tahoma 55 2 122 CrEaTiViTy | drawtext -ron $swin %S tahoma 55 2 124 CrEaTiViTy | drawtext -ron $swin 0 tahoma 55 1 123 CrEaTiViTy
  drawscroll -n $swin 0 5 0 0 5 100 0 5 305 0 5 100 0 -5 0 115 5 100 0 -5 305 115 5 100 0 4 5 0 5 100 0 4 300 0 5 100 0 -4 5 115 5 100 0 -4 300 115 5 100 0 3 10 0 5 100 0 3 295 0 5 100 0 -3 10 115 5 100 0 -3 295 115 5 100 0 2 15 0 5 100 0 2 290 0 5 100 0 -2 15 115 5 100 0 -2 290 115 5 100 0 1 20 0 5 100 0 1 285 0 5 100 0 -1 20 115 5 100 0 -1 285 115 5 100
  drawscroll -n $swin 0 0 25 0 5 100 0 0 280 0 5 100 0 0 25 115 5 100 0 0 280 115 5 100 0 -1 30 0 5 100 0 -1 275 0 5 100 0 1 30 115 5 100 0 1 275 115 5 100 0 -2 35 0 5 100 0 -2 270 0 5 100 0 2 35 115 5 100 0 2 270 115 5 100 0 -3 40 0 5 100 0 -3 265 0 5 100 0 3 40 115 5 100 0 3 265 115 5 100 0 -4 45 0 5 100 0 -4 260 0 5 100 0 4 45 115 5 100 0 4 260 115 5 100
  drawscroll -n $swin 0 -5 50 0 5 100 0 -5 255 0 5 100 0 5 50 115 5 100 0 5 255 115 5 100 0 -6 55 0 5 100 0 -6 250 0 5 100 0 6 55 115 5 100 0 6 250 115 5 100 0 -7 60 0 5 100 0 -7 245 0 5 100 0 7 60 115 5 100 0 7 245 115 5 100 0 -8 65 0 5 100 0 -8 240 0 5 100 0 8 65 115 5 100 0 8 240 115 5 100 0 -9 70 0 5 100 0 -9 235 0 5 100 0 9 70 115 5 100 0 9 235 115 5 100
  drawscroll -n $swin 0 -10 75 0 5 100 0 -10 230 0 5 100 0 10 75 115 5 100 0 10 230 115 5 100 0 -11 80 0 5 100 0 -11 225 0 5 100 0 11 80 115 5 100 0 11 225 115 5 100 0 -12 85 0 5 100 0 -12 220 0 5 100 0 12 85 115 5 100 0 12 220 115 5 100 0 -13 90 0 5 100 0 -13 215 0 5 100 0 13 90 115 5 100 0 13 215 115 5 100 0 -14 95 0 5 100 0 -14 210 0 5 100
  drawscroll -n $swin 0 14 95 115 5 100 0 14 210 115 5 100 0 -15 100 0 5 100 0 -15 205 0 5 100 0 15 100 115 5 100 0 15 205 115 5 100 0 -16 105 0 5 100 0 -16 200 0 5 100 0 16 105 115 5 100 0 16 200 115 5 100 0 -17 110 0 5 100 0 -17 195 0 5 100 0 17 110 115 5 100 0 17 195 115 5 100 0 -18 115 0 5 100 0 -18 190 0 5 100 0 18 115 115 5 100 0 18 190 115 5 100
  drawscroll -n $swin 0 -19 120 0 5 100 0 -19 185 0 5 100 0 19 120 115 5 100 0 19 185 115 5 100 0 -20 125 0 5 100 0 -20 180 0 5 100 0 20 125 115 5 100 0 20 180 115 5 100 0 -19 130 0 5 100 0 -19 175 0 5 100 0 19 130 115 5 100 0 19 175 115 5 100 0 -20 135 0 5 100 0 -20 170 0 5 100 0 20 135 115 5 100 0 20 170 115 5 100 0 -19 140 0 5 100 0 -19 165 0 5 100
  drawscroll -n $swin 0 19 140 115 5 100 0 19 165 115 5 100 0 -20 145 0 5 100 0 -20 160 0 5 100 0 20 145 115 5 100 0 20 160 115 5 100 0 -19 150 0 5 100 0 -19 155 0 5 100 0 19 150 115 5 100 0 19 155 115 5 100 | drawtext -rn $swin 51200 webdings 30 5 85 $chr(%y) | drawrect -ren $swin 51200 1 5 86 30 30 | drawfill -rn $swin 13107200 51200 17 105
  drawtext -rn $swin %S webdings 25 140 50 $chr(196) | drawtext -rn $swin %S webdings 25 140 125 $chr(133) | drawcopy -n $swin 4 85 32 32 $swin 269 85 | if (%k = 1) %C = SykO | if (%k = 2) %C = LInk | if (%k = 3) %C = ShOwInG CrEaTiViTy | if (%k = 4) %C = with mIRC PicWins | if (%k = 5) || (%k = 7) || (%k = 8) || (%k = 10) || (%k = 11) %C = $chr(160)
  if (%k = 6) %C = PicWin TeAm | if (%k = 9) %C = Created by SykO | %z = $calc((305 - $width(%C,tahoma,20,1,0)) / 2) | drawtext -ron $swin 16749378 tahoma 20 $calc(%z - 1) 87 %C | drawtext -ron $swin 16749378 tahoma 20 $calc(%z - 1) 89 %C | drawtext -ron $swin 16749378 tahoma 20 $calc(%z + 1) 87 %C | drawtext -ron $swin 16749378 tahoma 20 $calc(%z + 1) 89 %C
  drawtext -ron $swin 0 tahoma 20 %z 88 %C | while (%r <= 10) { drawdot -rn $swin $rgb($r(0,255),$r(0,255),$r(0,255)) 1 $r(5,300) $r(5,195) $r(5,300) $r(5,195) $r(5,300) $r(5,195) $r(5,300) $r(5,195) $r(5,300) $r(5,195) | inc %r } | drawdot $swin
  %O = $iif(%O != 3,$calc(%O + 1),1) | .timersc -m 1 500 scani $iif(%S == 16749378,13472528,16749378) $iif(%y != 254,$calc(%y + 1),252) $iif(%O == 3,$iif(%k != 11,$calc(%k + 1),1),%k) %O
}
menu @ShOwInG-CrEaTiViTy {
  dclick: window -c @ShOwInG-CrEaTiViTy
}
avatar
SykO

Mensajes : 4
Fecha de inscripción : 13/12/2010

Ver perfil de usuario

Volver arriba Ir abajo

Ver el tema anterior Ver el tema siguiente Volver arriba


 
Permisos de este foro:
No puedes responder a temas en este foro.